Bus e protocolli seriali con Arduino

// Arduino A: legge un potenziometro e lo invia
#include <SoftwareSerial.h>
SoftwareSerial link(10, 11);   // RX, TX

void setup() {
  link.begin(9600);
}

void loop() {
  int v = analogRead(A0);      // 0..1023
  link.println(v);             // testo + "\r\n"
  delay(200);
}

// Arduino B: riceve e mostra sul Monitor seriale
#include <SoftwareSerial.h>
SoftwareSerial link(10, 11);   // RX, TX

void setup() {
  Serial.begin(9600);          // verso il PC
  link.begin(9600);            // verso Arduino A
}

void loop() {
  if (link.available()) {
    String riga = link.readStringUntil('\n');
    Serial.print("Ricevuto: ");
    Serial.println(riga);
  }
}

// 8 LED su uno shift register 74HC595 via SPI
#include <SPI.h>
const int LATCH = 10;          // ST_CP (pin 12 del 595)

void setup() {
  pinMode(LATCH, OUTPUT);
  SPI.begin();
}

void scrivi(byte b) {
  SPI.beginTransaction(SPISettings(1000000, MSBFIRST, SPI_MODE0));
  digitalWrite(LATCH, LOW);
  SPI.transfer(b);
  digitalWrite(LATCH, HIGH);   // le uscite si aggiornano qui
  SPI.endTransaction();
}

void loop() {
  for (int i = 0; i < 8; i++) {
    scrivi(1 << i);            // luce che scorre
    delay(150);
  }
}

#include <Wire.h>

void setup() {
  Wire.begin();
  Serial.begin(9600);
  Serial.println("Scansione I2C...");
  for (byte ind = 1; ind < 127; ind++) {
    Wire.beginTransmission(ind);
    if (Wire.endTransmission() == 0) {   // 0 = ACK
      Serial.print("Trovato: 0x");
      if (ind < 16) Serial.print('0');
      Serial.println(ind, HEX);
    }
  }
  Serial.println("Fine.");
}

void loop() {}

// Libreria: LiquidCrystal I2C (Gestore librerie)
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
LiquidCrystal_I2C lcd(0x27, 16, 2);  // indirizzo dallo scanner

void setup() {
  lcd.init();
  lcd.backlight();
  lcd.print("Ciao 5a!");
}

void loop() {
  lcd.setCursor(0, 1);
  lcd.print("t = ");
  lcd.print(millis() / 1000);
  lcd.print(" s   ");
  delay(250);
}

// Due Arduino: il master invia al nodo 8
#include <Wire.h>

void setup() { Wire.begin(); }       // senza indirizzo = master

void loop() {
  byte v = analogRead(A0) >> 2;      // 0..255
  Wire.beginTransmission(8);
  Wire.write(v);
  Wire.endTransmission();
  delay(100);
}

#include <Wire.h>
volatile byte valore = 0;

void ricevi(int n) {                 // chiamata a ogni messaggio
  while (Wire.available()) valore = Wire.read();
}

void setup() {
  Wire.begin(8);                     // io sono il nodo 8
  Wire.onReceive(ricevi);
  pinMode(9, OUTPUT);
}

void loop() { analogWrite(9, valore); }

#include <OneWire.h>
#include <DallasTemperature.h>

OneWire bus(2);                      // DQ sul pin 2
DallasTemperature sensori(&bus);

void setup() {
  Serial.begin(9600);
  sensori.begin();
  Serial.print("Sensori trovati: ");
  Serial.println(sensori.getDeviceCount());
}

void loop() {
  sensori.requestTemperatures();     // avvia la conversione
  float t = sensori.getTempCByIndex(0);
  Serial.println(t);                 // -127 = sensore non trovato
  delay(1000);
}

DeviceAddress ind;
for (int i = 0; i < sensori.getDeviceCount(); i++) {
  sensori.getAddress(ind, i);
  Serial.print("Sensore ");
  Serial.print(i);
  Serial.print(": ");
  for (int j = 0; j < 8; j++) {
    if (ind[j] < 16) Serial.print('0');
    Serial.print(ind[j], HEX);
  }
  Serial.println();                  // il primo byte è 28 = DS18B20
}